Commit 0d05567a authored by Ram-Z's avatar Ram-Z

s-nail: add new pkg

parent 3f1ed18f
# Maintainer: Ram-Z <ram-z[at]chakraos[dot]org>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s@arch@gmail.com>
# Contributor: Andreas Wagner <Andreas.Wagner@em.uni-frankfurt.de>
pkgname=s-nail
pkgver=14.8.8
pkgrel=1
pkgdesc='Mail processing system with a command syntax reminiscent of ed'
url='http://www.sdaoden.eu/code.html#s-nail'
license=('custom:BSD')
arch=('i686' 'x86_64')
depends=('openssl' 'krb5')
optdepends=('smtp-forwarder: for sending mail')
validpgpkeys=('232C220BCB5690A37BD22FFDEB66022795F382CE')
source=("https://www.sdaoden.eu/downloads/${pkgname}-${pkgver}.tar"{.xz,.asc})
sha1sums=('5cca53ed48e85edf4310700ce7264f8b253fe44c' 'SKIP')
groups=('base')
backup=('etc/mail.rc')
replaces=('mailx' 'mailx-heirloom' 'heirloom-mailx')
provides=('mailx' 'mailx-heirloom' 'heirloom-mailx')
conflicts=('mailx' 'mailx-heirloom' 'heirloom-mailx')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
CFLAGS+=" $CPPFLAGS"
make \
PREFIX=/usr \
SYSCONFDIR=/etc \
LIBEXECDIR=/usr/lib \
MAILSPOOL=/var/spool/mail \
SID= NAIL=mail \
WANT_AUTOCC=0 \
config
make build
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
make test
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" packager-install
ln -sf mail "${pkgdir}"/usr/bin/mailx
ln -sf mail.1.gz "${pkgdir}"/usr/share/man/man1/mailx.1.gz
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
Markdown is supported
0% or .
You are about to add 0 people to the discussion. Proceed with caution.
Finish editing this message first!
Please register or to comment