[skip-ci] spice-vdagent: added to repo

spice-vdagent/PKGBUILD

+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: mutantmonkey <aur@mutantmonkey.in>
+
+pkgname=spice-vdagent
+pkgver=0.19.0
+pkgrel=1
+pkgdesc="Spice agent for Linux guests"
+arch=('x86_64')
+url="https://www.spice-space.org/"
+license=('GPL')
+depends=('alsa-lib' 'dbus' 'glib2' 'libpciaccess' 'libxfixes' 'libxinerama' 'libxrandr' 'systemd' 'libdrm')
+makedepends=('spice-protocol')
+backup=('etc/conf.d/spice-vdagentd')
+source=("https://www.spice-space.org/download/releases/$pkgname-$pkgver.tar.bz2"{,.sig})
+sha256sums=('63a77c611c84f8120519a78a30256e43e159085831ac82de71643db643972f65'
+            'SKIP')
+validpgpkeys=('206D3B352F566F3B0E6572E997D9123DE37A484F')
+
+prepare() {
+	cd $pkgname-$pkgver
+	sed -i 's|/etc/sysconfig/spice-vdagentd|/etc/conf.d/spice-vdagentd|
+	        s|/usr/sbin/spice-vdagentd|/usr/bin/spice-vdagentd|' data/spice-vdagentd.service
+	sed -i 's|/etc/sysconfig/spice-vdagentd|/etc/conf.d/spice-vdagentd|' data/spice-vdagentd.1.in
+}
+
+build() {
+	cd $pkgname-$pkgver
+	./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --sbindir=/usr/bin \
+	            --with-session-info=systemd --with-init-script=systemd
+	make
+}
+
+package() {
+	cd $pkgname-$pkgver
+	make DESTDIR="$pkgdir" install
+	rm -r "$pkgdir/var"
+	install -dm755 "$pkgdir/etc/conf.d/"
+	echo 'SPICE_VDAGENTD_EXTRA_ARGS=""' > "$pkgdir/etc/conf.d/spice-vdagentd"
+}