astyle, autoconf-archive, beanshell, bogofilter, bootchart: moved from core to desktop, FS#1866

astyle/PKGBUILD

+# Maintainer: Giuseppe Calà <jiveaxe@gmail.com>
+
+pkgname=astyle
+pkgver=2.05.1
+pkgrel=1
+pkgdesc="Artistic Style is a source code indenter, formatter, and beautifier for the C, C++, C# and Java programming languages."
+arch=('x86_64')
+url="http://astyle.sourceforge.net/ "
+license=('LGPL')
+source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}_${pkgver}_linux.tar.gz)
+md5sums=('4142d178047d7040da3e0e2f1b030a1a')
+
+build() {
+  cd ${srcdir}/${pkgname}/build/gcc
+  make
+}
+
+package() {
+  cd ${srcdir}/${pkgname}/build/gcc/bin
+  install -D -m755 -o root -g root astyle ${pkgdir}/usr/bin/astyle
+
+  for files in `find ${srcdir}/${pkgname}/doc -name *.html`
+	do
+	    mkdir -p $pkgdir/usr/share/astyle
+	    cp $files $pkgdir/usr/share/astyle
+	done
+
+  for files in `find ${srcdir}/${pkgname}/doc -name *.css`
+	do
+	    mkdir -p $pkgdir/usr/share/astyle
+	    cp $files $pkgdir/usr/share/astyle
+	done
+}

autoconf-archive/PKGBUILD

+# Arch contributor: https://projects.archlinux.org/svntogit/community.git/plain/trunk/PKGBUILD?h=packages/autoconf-archive
+
+pkgname=autoconf-archive
+pkgver=2016.09.16
+pkgrel=1
+epoch=1
+pkgdesc="A collection of freely re-usable Autoconf macros"
+arch=('any')
+url="http://www.gnu.org/software/autoconf-archive/"
+_watch="http://mirrors.axint.net/repos/gnu.org/autoconf-archive/"
+license=('GPL')
+depends=('autoconf')
+optdepends=('automake: macros for use with it')
+validpgpkeys=('1A4F63A13A4649B632F65EE141BC28FE99089D72')
+source=(http://ftpmirror.gnu.org/$pkgname/$pkgname-$pkgver.tar.xz{,.sig})
+md5sums=('bf19d4cddce260b3c3e1d51d42509071'
+         'SKIP')
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+  ./configure --prefix=/usr
+  make
+}
+
+check() {
+  cd "$srcdir/$pkgname-$pkgver"
+  make check
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+  make DESTDIR="$pkgdir/" install
+}

beanshell/PKGBUILD

+#
+# Chakra Packages for Chakra, part of chakra-project.org
+#
+# maintainer (x86_64): AlmAck <almack[at]chakra-project[dot]org>
+
+pkgname=beanshell
+pkgver=2.1.7
+pkgrel=1
+pkgdesc="Small, free, embeddable, source level Java interpreter with object based scripting language features written in Java"
+arch=('any')
+url="https://code.google.com/p/beanshell2/"
+license=('LGPL')
+depends=('java-runtime')
+provides=('bsh')
+source=("https://beanshell2.googlecode.com/files/bsh-${pkgver}.jar")
+noextract=("${pkgname}-${pkgver}.jar")
+md5sums=('0d60db994fe371594f6b513bf07768cf')
+
+build() {
+  install -m755 -d ${pkgdir}/usr/share/java/
+  install -D -m644 ${srcdir}/bsh-${pkgver}.jar ${pkgdir}/usr/share/java/bsh.jar
+}

bogofilter/PKGBUILD

+pkgname=bogofilter
+pkgver=1.2.4
+pkgrel=2
+pkgdesc="A fast Bayesian spam filtering tool"
+arch=('x86_64')
+license=(GPL3)
+url="http://bogofilter.sourceforge.net"
+depends=('db' 'perl' 'gsl')
+backup=(etc/bogofilter/bogofilter.cf)
+source=("http://sourceforge.net/projects/${pkgname}/files/${pkgname}-current/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.bz2")
+md5sums=('d0a5eebb3274b23ceabe766a6443a1c5')
+
+build() {
+  cd ${srcdir}/${pkgname}-${pkgver}
+  ./configure --prefix=/usr \
+              --sysconfdir=/etc/bogofilter  \
+              --localstatedir=/var \
+              --enable-transactions \
+              --with-database=db
+
+  make
+}
+
+package() {
+  cd ${srcdir}/${pkgname}-${pkgver}
+  make DESTDIR=${pkgdir} install
+
+  mv ${pkgdir}/etc/bogofilter/bogofilter.cf.example ${pkgdir}/etc/bogofilter/bogofilter.cf
+
+  install -dm755 ${pkgdir}/usr/share/${pkgname}/contrib
+  install -m644 contrib/* ${pkgdir}/usr/share/${pkgname}/contrib/
+}

bootchart/PKGBUILD

+# Platform Packages for Chakra, part of chakra-project.org
+#
+# maintainer abveritas@chakra-project.org
+
+pkgname=bootchart
+pkgver=1.20
+pkgrel=1
+pkgdesc="Tool that collects and graphs the CPU and disk load of the system as it works"
+url="https://github.com/sofar/bootchart"
+license=('GPL2')
+arch=('x86_64')
+depends=('glibc')
+source=("http://foo-projects.org/~sofar/${pkgname}/${pkgname}-${pkgver}.tar.gz")
+md5sums=('071c67856a2b16e1a9e93a058de3eb65')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  ./configure --prefix=/usr --sbindir=/usr/bin
+
+   make
+}
+
+package() {
+  cd "$srcdir/${pkgname}-${pkgver}"
+
+  make DESTDIR="${pkgdir}" install
+}