Commit f91a82c9 authored by Chaoting Liu's avatar Chaoting Liu

[skip-ci] gjs: import as ostree dependency

parent 4ae0ec20
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
pkgname=gjs
pkgver=1.56.0
pkgrel=1
epoch=2
pkgdesc="Javascript Bindings for GNOME"
url="https://wiki.gnome.org/Projects/Gjs"
arch=(x86_64)
license=(GPL)
depends=(cairo gobject-introspection-runtime js60 gtk3)
makedepends=(gobject-introspection git autoconf-archive)
checkdepends=(valgrind xorg-server-xvfb)
_commit=31a0ed59b2c1c621410269e17740b133e73f7334 # tags/1.56.0^0
source=("git+https://gitlab.gnome.org/GNOME/gjs.git#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgname
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgname
./configure \
--prefix=/usr \
--libexecdir=/usr/lib \
--disable-static \
--enable-compile-warnings=yes \
$(type -P Xvfb >/dev/null && echo --with-xvfb-tests)
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd $pkgname
make -j1 check
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
Markdown is supported
0% or
You are about to add 0 people to the discussion. Proceed with caution.
Finish editing this message first!
Please register or to comment